mirror of
https://github.com/Cisco-Talos/clamav.git
synced 2025-10-19 10:23:17 +00:00
2552cfd0d1
An ENABLE_TESTS CMake option is provided so that users can disable testing if they don't want it. Instructions for how to use this included in the INSTALL.cmake.md file. If you run `ctest`, each testcase will write out a log file to the <build>/unit_tests directory. As with Autotools' make check, the test files are from test/.split and unit_tests/.split files, but for CMake these are generated at build time instead of at test time. On Posix systems, sets the LD_LIBRARY_PATH so that ClamAV-compiled libraries can be loaded when running tests. On Windows systems, CTest will identify and collect all library dependencies and assemble a temporarily install under the build/unit_tests directory so that the libraries can be loaded when running tests. The same feature is used on Windows when using CMake to install to collect all DLL dependencies so that users don't have to install them manually afterwards. Each of the CTest tests are run using a custom wrapper around Python's unittest framework, which is also responsible for finding and inserting valgrind into the valgrind tests on Posix systems. Unlike with Autotools, the CMake CTest Valgrind-tests are enabled by default, if Valgrind can be found. There's no need to set VG=1. CTest's memcheck module is NOT supported, because we use Python to orchestrate our tests. Added a bunch of Windows compatibility changes to the unit tests. These were primarily changing / to PATHSEP and making adjustments to use Win32 C headers and ifdef out the POSIX ones which aren't available on Windows. Also disabled a bunch of tests on Win32 that don't work on Windows, notably the mmap ones and FD-passing (i.e. FILEDES) ones. Add JSON_C_HAVE_INTTYPES_H definition to clamav-config.h to eliminate warnings on Windows where json.h is included after inttypes.h because json-c's inttypes replacement relies on it. This is a it of a hack and may be removed if json-c fixes their inttypes header stuff in the future. Add preprocessor definitions on Windows to disable MSVC warnings about CRT secure and nonstandard functions. While there may be a better solution, this is needed to be able to see other more serious warnings. Add missing file comment block and copyright statement for clamsubmit.c. Also change json-c/json.h include filename to json.h in clamsubmit.c. The directory name is not required. Changed the hash table data integer type from long, which is poorly defined, to size_t -- which is capable of storing a pointer. Fixed a bunch of casts regarding this variable to eliminate warnings. Fixed two bugs causing utf8 encoding unit tests to fail on Windows: - The in_size variable should be the number of bytes, not the character count. This was was causing the SHIFT_JIS (japanese codepage) to UTF8 transcoding test to only transcode half the bytes. - It turns out that the MultiByteToWideChar() API can't transcode UTF16-BE to UTF16-LE. The solution is to just iterate over the buffer and flip the bytes on each uint16_t. This but was causing the UTF16-BE to UTF8 tests to fail. I also split up the utf8 transcoding tests into separate tests so I could see all of the failures instead of just the first one. Added a flags parameter to the unit test function to open testfiles because it turns out that on Windows if a file contains the \r\n it will replace it with just \n if you opened the file as a text file instead of as binary. However, if we open the CBC files as binary, then a bunch of bytecode tests fail. So I've changed the tests to open the CBC files in the bytecode tests as text files and open all other files as binary. Ported the feature tests from shell scripts to Python using a modified version of our QA test-framework, which is largely compatible and will allow us to migrate some QA tests into this repo. I'd like to add GitHub Actions pipelines in the future so that all public PR's get some testing before anyone has to manually review them. The clamd --log option was missing from the help string, though it definitely works. I've added it in this commit. It appears that clamd.c was never clang-format'd, so this commit also reformats clamd.c. Some of the check_clamd tests expected the path returned by clamd to match character for character with original path sent to clamd. However, as we now evaluate real paths before a scan, the path returned by clamd isn't going to match the relative (and possibly symlink-ridden) path passed to clamdscan. I fixed this test by changing the test to search for the basename: <signature> FOUND within the response instead of matching the exact path. Autotools: Link check_clamd with libclamav so we can use our utility functions in check_clamd.c.
124 lines
3.3 KiB
CMake
Executable file
124 lines
3.3 KiB
CMake
Executable file
# Copyright 2019 Collabora, Ltd.
|
|
# Distributed under the Boost Software License, Version 1.0.
|
|
# (See accompanying file LICENSE_1_0.txt or copy at
|
|
# http://www.boost.org/LICENSE_1_0.txt)
|
|
#
|
|
# Original Author:
|
|
# 2019 Ryan Pavlik <ryan.pavlik@collabora.com>
|
|
|
|
#.rst:
|
|
# FindCheck
|
|
# ---------------
|
|
#
|
|
# Find the "Check" C unit testing framework.
|
|
#
|
|
# See https://libcheck.github.io
|
|
#
|
|
# The Debian package for this is called ``check``
|
|
#
|
|
# Targets
|
|
# ^^^^^^^
|
|
#
|
|
# If successful, the following imported targets are created.
|
|
#
|
|
# ``libcheck::check``
|
|
#
|
|
# Cache variables
|
|
# ^^^^^^^^^^^^^^^
|
|
#
|
|
# The following cache variable may also be set to assist/control the operation of this module:
|
|
#
|
|
# ``LIBCHECK_ROOT_DIR``
|
|
# The root to search for libcheck.
|
|
|
|
set(LIBCHECK_ROOT_DIR "${LIBCHECK_ROOT_DIR}" CACHE PATH "Root to search for libcheck")
|
|
|
|
find_package(PkgConfig QUIET)
|
|
if(PKG_CONFIG_FOUND)
|
|
set(_old_prefix_path "${CMAKE_PREFIX_PATH}")
|
|
# So pkg-config uses LIBCHECK_ROOT_DIR too.
|
|
if(LIBCHECK_ROOT_DIR)
|
|
list(APPEND CMAKE_PREFIX_PATH ${LIBCHECK_ROOT_DIR})
|
|
endif()
|
|
pkg_check_modules(PC_LIBCHECK QUIET check)
|
|
# Restore
|
|
set(CMAKE_PREFIX_PATH "${_old_prefix_path}")
|
|
endif()
|
|
find_path(LIBCHECK_INCLUDE_DIR
|
|
NAMES
|
|
check.h
|
|
PATHS
|
|
${LIBCHECK_ROOT_DIR}
|
|
HINTS
|
|
${PC_LIBCHECK_INCLUDE_DIRS}
|
|
PATH_SUFFIXES
|
|
include
|
|
)
|
|
find_library(LIBCHECK_LIBRARY
|
|
NAMES
|
|
check_pic
|
|
check
|
|
PATHS
|
|
${LIBCHECK_ROOT_DIR}
|
|
HINTS
|
|
${PC_LIBCHECK_LIBRARY_DIRS}
|
|
PATH_SUFFIXES
|
|
lib
|
|
)
|
|
find_library(LIBCHECK_SUBUNIT_LIBRARY
|
|
NAMES
|
|
subunit
|
|
PATHS
|
|
${LIBCHECK_ROOT_DIR}
|
|
HINTS
|
|
${PC_LIBCHECK_LIBRARY_DIRS}
|
|
PATH_SUFFIXES
|
|
lib
|
|
)
|
|
find_library(LIBCHECK_LIBRT rt)
|
|
find_library(LIBCHECK_LIBM m)
|
|
|
|
find_package(Threads QUIET)
|
|
|
|
set(_libcheck_extra_required)
|
|
if(PC_LIBCHECK_FOUND AND "${PC_LIBCHECK_LIBRARIES}" MATCHES "subunit")
|
|
list(APPEND _libcheck_extra_required LIBCHECK_SUBUNIT_LIBRARY)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(Libcheck
|
|
REQUIRED_VARS
|
|
LIBCHECK_INCLUDE_DIR
|
|
LIBCHECK_LIBRARY
|
|
THREADS_FOUND
|
|
)
|
|
if(LIBCHECK_FOUND)
|
|
if(NOT TARGET libcheck::check)
|
|
add_library(libcheck::check UNKNOWN IMPORTED)
|
|
|
|
set_target_properties(libcheck::check PROPERTIES
|
|
INTERFACE_INCLUDE_DIRECTORIES "${LIBCHECK_INCLUDE_DIR}")
|
|
set_target_properties(libcheck::check PROPERTIES
|
|
IMPORTED_LINK_INTERFACE_LANGUAGES "C"
|
|
IMPORTED_LOCATION ${LIBCHECK_LIBRARY})
|
|
set_property(TARGET libcheck::check PROPERTY
|
|
IMPORTED_LINK_INTERFACE_LIBRARIES Threads::Threads)
|
|
|
|
# if we found librt or libm, link them.
|
|
if(LIBCHECK_LIBRT)
|
|
set_property(TARGET libcheck::check APPEND PROPERTY
|
|
IMPORTED_LINK_INTERFACE_LIBRARIES "${LIBCHECK_LIBRT}")
|
|
endif()
|
|
if(LIBCHECK_LIBM)
|
|
set_property(TARGET libcheck::check APPEND PROPERTY
|
|
IMPORTED_LINK_INTERFACE_LIBRARIES "${LIBCHECK_LIBM}")
|
|
endif()
|
|
if(LIBCHECK_SUBUNIT_LIBRARY)
|
|
set_property(TARGET libcheck::check APPEND PROPERTY
|
|
IMPORTED_LINK_INTERFACE_LIBRARIES "${LIBCHECK_SUBUNIT_LIBRARY}")
|
|
endif()
|
|
|
|
endif()
|
|
mark_as_advanced(LIBCHECK_INCLUDE_DIR LIBCHECK_LIBRARY LIBCHECK_SUBUNIT_LIBRARY)
|
|
endif()
|
|
mark_as_advanced(LIBCHECK_ROOT_DIR LIBCHECK_LIBRT LIBCHECK_LIBM)
|