mirror of
https://github.com/python/cpython.git
synced 2025-10-31 13:41:24 +00:00
d48cc82ed2
This patch properly quotes template strings in `venv` activation scripts. This mitigates potential command injection.
27 lines
937 B
Tcsh
27 lines
937 B
Tcsh
# This file must be used with "source bin/activate.csh" *from csh*.
|
|
# You cannot run it directly.
|
|
|
|
# Created by Davide Di Blasi <davidedb@gmail.com>.
|
|
# Ported to Python 3.3 venv by Andrew Svetlov <andrew.svetlov@gmail.com>
|
|
|
|
alias deactivate 'test $?_OLD_VIRTUAL_PATH != 0 && setenv PATH "$_OLD_VIRTUAL_PATH" && unset _OLD_VIRTUAL_PATH; rehash; test $?_OLD_VIRTUAL_PROMPT != 0 && set prompt="$_OLD_VIRTUAL_PROMPT" && unset _OLD_VIRTUAL_PROMPT; unsetenv VIRTUAL_ENV; unsetenv VIRTUAL_ENV_PROMPT; test "\!:*" != "nondestructive" && unalias deactivate'
|
|
|
|
# Unset irrelevant variables.
|
|
deactivate nondestructive
|
|
|
|
setenv VIRTUAL_ENV __VENV_DIR__
|
|
|
|
set _OLD_VIRTUAL_PATH="$PATH"
|
|
setenv PATH "$VIRTUAL_ENV/"__VENV_BIN_NAME__":$PATH"
|
|
setenv VIRTUAL_ENV_PROMPT __VENV_PROMPT__
|
|
|
|
|
|
set _OLD_VIRTUAL_PROMPT="$prompt"
|
|
|
|
if (! "$?VIRTUAL_ENV_DISABLE_PROMPT") then
|
|
set prompt = "("__VENV_PROMPT__") $prompt:q"
|
|
endif
|
|
|
|
alias pydoc python -m pydoc
|
|
|
|
rehash
|