mirror of
https://github.com/godotengine/godot.git
synced 2025-12-07 13:49:54 +00:00
628df323e2
Also optimize all tonemappers to perform less calculations per-pixel. Note: unlike `white`, `agx_white` is limited to a minimum of `2.0` and defaults to `16.29`. When using a RGB10A2 render buffer, `agx_white` will be ignored and a value of `2.0` will be used instead to ensure good behavior on the Mobile renderer.
199 lines
8.3 KiB
GLSL
199 lines
8.3 KiB
GLSL
layout(std140) uniform TonemapData { //ubo:0
|
|
float exposure;
|
|
int tonemapper;
|
|
int pad;
|
|
int pad2;
|
|
vec4 tonemapper_params;
|
|
float brightness;
|
|
float contrast;
|
|
float saturation;
|
|
int pad3;
|
|
};
|
|
|
|
// This expects 0-1 range input.
|
|
vec3 linear_to_srgb(vec3 color) {
|
|
//color = clamp(color, vec3(0.0), vec3(1.0));
|
|
//const vec3 a = vec3(0.055f);
|
|
//return mix((vec3(1.0f) + a) * pow(color.rgb, vec3(1.0f / 2.4f)) - a, 12.92f * color.rgb, lessThan(color.rgb, vec3(0.0031308f)));
|
|
// Approximation from http://chilliant.blogspot.com/2012/08/srgb-approximations-for-hlsl.html
|
|
return max(vec3(1.055) * pow(color, vec3(0.416666667)) - vec3(0.055), vec3(0.0));
|
|
}
|
|
|
|
// This expects 0-1 range input, outside that range it behaves poorly.
|
|
vec3 srgb_to_linear(vec3 color) {
|
|
// Approximation from http://chilliant.blogspot.com/2012/08/srgb-approximations-for-hlsl.html
|
|
return color * (color * (color * 0.305306011 + 0.682171111) + 0.012522878);
|
|
}
|
|
|
|
#ifdef APPLY_TONEMAPPING
|
|
|
|
// Based on Reinhard's extended formula, see equation 4 in https://doi.org/cjbgrt
|
|
vec3 tonemap_reinhard(vec3 color) {
|
|
float white_squared = tonemapper_params.x;
|
|
vec3 white_squared_color = white_squared * color;
|
|
// Equivalent to color * (1 + color / white_squared) / (1 + color)
|
|
return (white_squared_color + color * color) / (white_squared_color + white_squared);
|
|
}
|
|
|
|
vec3 tonemap_filmic(vec3 color) {
|
|
// These constants must match the those in the C++ code that calculates the parameters.
|
|
// exposure_bias: Input scale (color *= bias, env->white *= bias) to make the brightness consistent with other tonemappers.
|
|
// Also useful to scale the input to the range that the tonemapper is designed for (some require very high input values).
|
|
// Has no effect on the curve's general shape or visual properties.
|
|
const float exposure_bias = 2.0f;
|
|
const float A = 0.22f * exposure_bias * exposure_bias; // bias baked into constants for performance
|
|
const float B = 0.30f * exposure_bias;
|
|
const float C = 0.10f;
|
|
const float D = 0.20f;
|
|
const float E = 0.01f;
|
|
const float F = 0.30f;
|
|
|
|
vec3 color_tonemapped = ((color * (A * color + C * B) + D * E) / (color * (A * color + B) + D * F)) - E / F;
|
|
|
|
return color_tonemapped / tonemapper_params.x;
|
|
}
|
|
|
|
// Adapted from https://github.com/TheRealMJP/BakingLab/blob/master/BakingLab/ACES.hlsl
|
|
// (MIT License).
|
|
vec3 tonemap_aces(vec3 color) {
|
|
// These constants must match the those in the C++ code that calculates the parameters.
|
|
const float exposure_bias = 1.8f;
|
|
const float A = 0.0245786f;
|
|
const float B = 0.000090537f;
|
|
const float C = 0.983729f;
|
|
const float D = 0.432951f;
|
|
const float E = 0.238081f;
|
|
|
|
// Exposure bias baked into transform to save shader instructions. Equivalent to `color *= exposure_bias`
|
|
const mat3 rgb_to_rrt = mat3(
|
|
vec3(0.59719f * exposure_bias, 0.35458f * exposure_bias, 0.04823f * exposure_bias),
|
|
vec3(0.07600f * exposure_bias, 0.90834f * exposure_bias, 0.01566f * exposure_bias),
|
|
vec3(0.02840f * exposure_bias, 0.13383f * exposure_bias, 0.83777f * exposure_bias));
|
|
|
|
const mat3 odt_to_rgb = mat3(
|
|
vec3(1.60475f, -0.53108f, -0.07367f),
|
|
vec3(-0.10208f, 1.10813f, -0.00605f),
|
|
vec3(-0.00327f, -0.07276f, 1.07602f));
|
|
|
|
color *= rgb_to_rrt;
|
|
vec3 color_tonemapped = (color * (color + A) - B) / (color * (C * color + D) + E);
|
|
color_tonemapped *= odt_to_rgb;
|
|
|
|
return color_tonemapped / tonemapper_params.x;
|
|
}
|
|
|
|
// allenwp tonemapping curve; developed for use in the Godot game engine.
|
|
// Source and details: https://allenwp.com/blog/2025/05/29/allenwp-tonemapping-curve/
|
|
// Input must be a non-negative linear scene value.
|
|
vec3 allenwp_curve(vec3 x) {
|
|
const float output_max_value = 1.0; // SDR always has an output_max_value of 1.0
|
|
|
|
// These constants must match the those in the C++ code that calculates the parameters.
|
|
// 18% "middle gray" is perceptually 50% of the brightness of reference white.
|
|
const float awp_crossover_point = 0.18;
|
|
// When output_max_value and/or awp_crossover_point are no longer constant,
|
|
// awp_shoulder_max can be calculated on the CPU and passed in as tonemap_e.
|
|
const float awp_shoulder_max = output_max_value - awp_crossover_point;
|
|
|
|
float awp_contrast = tonemapper_params.x;
|
|
float awp_toe_a = tonemapper_params.y;
|
|
float awp_slope = tonemapper_params.z;
|
|
float awp_w = tonemapper_params.w;
|
|
|
|
// Reinhard-like shoulder:
|
|
vec3 s = x - awp_crossover_point;
|
|
vec3 slope_s = awp_slope * s;
|
|
s = slope_s * (1.0 + s / awp_w) / (1.0 + (slope_s / awp_shoulder_max));
|
|
s += awp_crossover_point;
|
|
|
|
// Sigmoid power function toe:
|
|
vec3 t = pow(x, vec3(awp_contrast));
|
|
t = t / (t + awp_toe_a);
|
|
|
|
return mix(s, t, lessThan(x, vec3(awp_crossover_point)));
|
|
}
|
|
|
|
// This is an approximation and simplification of EaryChow's AgX implementation that is used by Blender.
|
|
// This code is based off of the script that generates the AgX_Base_sRGB.cube LUT that Blender uses.
|
|
// Source: https://github.com/EaryChow/AgX_LUT_Gen/blob/main/AgXBasesRGB.py
|
|
// Colorspace transformation source: https://www.colour-science.org:8010/apps/rgb_colourspace_transformation_matrix
|
|
vec3 tonemap_agx(vec3 color) {
|
|
// Input color should be non-negative!
|
|
// Large negative values in one channel and large positive values in other
|
|
// channels can result in a colour that appears darker and more saturated than
|
|
// desired after passing it through the inset matrix. For this reason, it is
|
|
// best to prevent negative input values.
|
|
// This is done before the Rec. 2020 transform to allow the Rec. 2020
|
|
// transform to be combined with the AgX inset matrix. This results in a loss
|
|
// of color information that could be correctly interpreted within the
|
|
// Rec. 2020 color space as positive RGB values, but is often not worth
|
|
// the performance cost of an additional matrix multiplication.
|
|
//
|
|
// Additionally, this AgX configuration was created subjectively based on
|
|
// output appearance in the Rec. 709 color gamut, so it is possible that these
|
|
// matrices will not perform well with non-Rec. 709 output (more testing with
|
|
// future wide-gamut displays is be needed).
|
|
// See this comment from the author on the decisions made to create the matrices:
|
|
// https://github.com/godotengine/godot-proposals/issues/12317#issuecomment-2835824250
|
|
|
|
// Combined Rec. 709 to Rec. 2020 and Blender AgX inset matrices:
|
|
const mat3 rec709_to_rec2020_agx_inset_matrix = mat3(
|
|
0.544814746488245, 0.140416948464053, 0.0888104196149096,
|
|
0.373787398372697, 0.754137554567394, 0.178871756420858,
|
|
0.0813978551390581, 0.105445496968552, 0.732317823964232);
|
|
|
|
// Combined inverse AgX outset matrix and Rec. 2020 to Rec. 709 matrices.
|
|
const mat3 agx_outset_rec2020_to_rec709_matrix = mat3(
|
|
1.96488741169489, -0.299313364904742, -0.164352742528393,
|
|
-0.855988495690215, 1.32639796461980, -0.238183969428088,
|
|
-0.108898916004672, -0.0270845997150571, 1.40253671195648);
|
|
|
|
const float output_max_value = 1.0; // SDR always has an output_max_value of 1.0
|
|
|
|
// Apply inset matrix.
|
|
color = rec709_to_rec2020_agx_inset_matrix * color;
|
|
|
|
// Use the allenwp tonemapping curve to match the Blender AgX curve while
|
|
// providing stability across all variable dyanimc range (SDR, HDR, EDR).
|
|
color = allenwp_curve(color);
|
|
|
|
// Clipping to output_max_value is required to address a cyan colour that occurs
|
|
// with very bright inputs.
|
|
color = min(vec3(output_max_value), color);
|
|
|
|
// Apply outset to make the result more chroma-laden and then go back to Rec. 709.
|
|
color = agx_outset_rec2020_to_rec709_matrix * color;
|
|
|
|
// Blender's lusRGB.compensate_low_side is too complex for this shader, so
|
|
// simply return the color, even if it has negative components. These negative
|
|
// components may be useful for subsequent color adjustments.
|
|
return color;
|
|
}
|
|
|
|
#define TONEMAPPER_LINEAR 0
|
|
#define TONEMAPPER_REINHARD 1
|
|
#define TONEMAPPER_FILMIC 2
|
|
#define TONEMAPPER_ACES 3
|
|
#define TONEMAPPER_AGX 4
|
|
|
|
vec3 apply_tonemapping(vec3 color) { // inputs are LINEAR
|
|
if (tonemapper == TONEMAPPER_LINEAR) {
|
|
return color;
|
|
}
|
|
|
|
// Ensure color values passed to tonemappers are positive.
|
|
// They can be negative in the case of negative lights, which leads to undesired behavior.
|
|
color = max(vec3(0.0), color);
|
|
|
|
if (tonemapper == TONEMAPPER_REINHARD) {
|
|
return tonemap_reinhard(color);
|
|
} else if (tonemapper == TONEMAPPER_FILMIC) {
|
|
return tonemap_filmic(color);
|
|
} else if (tonemapper == TONEMAPPER_ACES) {
|
|
return tonemap_aces(color);
|
|
} else { // TONEMAPPER_AGX
|
|
return tonemap_agx(color);
|
|
}
|
|
}
|
|
|
|
#endif // APPLY_TONEMAPPING
|